- SPORE moved into gui directory by default.

gui/Protocols/ccitt509-3.spdl

@@ -0,0 +1,55 @@
+# CCITT X.509 (3)
+#
+# Modelled after the description in the SPORE library
+# http://www.lsv.ens-cachan.fr/spore/ccittx509_3.html
+#
+# Note:
+# The protocol description also states that Xa and Ya should be fresh
+# this can not be verified using scyther
+#
+
+const pk: Function;
+secret sk: Function;
+inversekeys(pk,sk);
+usertype Timestamp;
+
+protocol ccitt509-3(I,R)
+{
+    role I
+    {
+        const Ta: Timestamp;
+        var Tb: Timestamp;
+        const Na,Xa,Ya: Nonce;
+        var Xb,Nb,Yb: Nonce;
+        send_1(I,R, I,{Ta, Na, R, Xa,{Ya}pk(R)}sk(I));
+        read_2(R,I, R,{Tb, Nb, I, Na, Xb,{Yb}pk(I)}sk(R));
+        send_3(I,R, I, {Nb}sk(I));
+        claim_I1(I,Nisynch);
+        claim_I2(I,Secret,Ya);
+        claim_I3(I,Secret,Yb);
+    }    
+    
+    role R
+    {
+        var Ta: Timestamp;
+        const Tb: Timestamp;
+        var Na,Xa,Ya: Nonce;
+        const Xb,Yb,Nb: Nonce;
+
+        read_1(I,R, I,{Ta, Na, R, Xa,{Ya}pk(R)}sk(I));
+        send_2(R,I, R,{Tb, Nb, I, Na, Xb,{Yb}pk(I)}sk(R));
+        read_3(I,R, I, {Nb}sk(I));
+        claim_R1(R,Nisynch);
+        claim_R2(R,Secret,Ya);
+        claim_R3(R,Secret,Yb);
+        # There should also be Fresh Xa and Fresh Ya claims here
+    }
+}
+
+const Alice,Bob,Eve: Agent;
+
+untrusted Eve;
+const ne: Nonce;
+const te: Timestamp;
+compromised sk(Eve);
+