/*
 * Modeled from ISO/IEC 9798
 * Modeler: Cas Cremers, Dec. 2010
 *
 * signature
 * one-pass
 * unilateral
 */
const Cert: Function;

protocol isoiec-9798-3-1(A,B)
{
	role A
	{
		fresh TNA: Nonce;
		fresh Text1,Text2: Ticket;

		claim(A,Running,B,TNA,Text1);
		send_1(A,B, Cert(A),TNA,B,Text2, { TNA, B, Text1 }sk(A) );
	}
	role B
	{
		var TNA: Nonce;
		var Text1,Text2: Ticket;

		recv_1(A,B, Cert(A),TNA,B,Text2, { TNA, B, Text1 }sk(A) );

		claim(B,Commit,A,TNA,Text1);
		claim(B,Alive);
		claim(B,Weakagree);
	}
}

