0f54f2ed23
SPORE:
- pk is not known to all agents, only pk(Simon) is known
- Use new naming convention:
- Protocol name starting with an @ means internal protocol
- For non internal protocols naming is as follows:
protocolname-variant^subprotocol
For example: yahalom-Lowe^KeyCompromise meaning the key compromise sub
protocol of the Lowe variant of the Yahalom protocol.
90 lines
2.0 KiB
Plaintext
90 lines
2.0 KiB
Plaintext
# BAN simplified version of Yahalom
|
|
#
|
|
# Modelled after the description in the SPORE library
|
|
# http://www.lsv.ens-cachan.fr/spore/yahalomBAN.html
|
|
#
|
|
# Note:
|
|
# This protocol uses a ticket so scyther will only be able to verify
|
|
# the protocol using the ARACHNE engine (-a)
|
|
#
|
|
|
|
secret k : Function;
|
|
|
|
usertype SessionKey;
|
|
const Fresh: Function;
|
|
const Compromised: Function;
|
|
|
|
protocol yahalom-BAN^KeyCompromise(C)
|
|
{
|
|
// Read the names of 3 agents and disclose a session between them including
|
|
// corresponding session key to simulate key compromise
|
|
role C {
|
|
const Ni,Nr: Nonce;
|
|
const Kir: SessionKey;
|
|
var I,R,S: Agent;
|
|
|
|
read_C1(C,C, I,R,S);
|
|
send_C2(C,C, I,Ni,
|
|
R,Nr,{I,Ni}k(R,S),
|
|
Nr,{R,Kir,Ni}k(I,S),
|
|
{I,Kir,Nr}k(R,S),
|
|
{Nr}Kir,
|
|
Kir
|
|
);
|
|
claim_C3(C,Empty, (Compromised,Kir));
|
|
}
|
|
}
|
|
|
|
|
|
|
|
protocol yahalom-BAN(I,R,S)
|
|
{
|
|
role I
|
|
{
|
|
const Ni: Nonce;
|
|
var Nr: Nonce;
|
|
var T: Ticket;
|
|
var Kir: SessionKey;
|
|
|
|
send_1(I,R, I,Ni);
|
|
read_3(S,I, Nr, {R,Kir,Ni}k(I,S), T );
|
|
send_4(I,R, T, {Nr}Kir );
|
|
|
|
claim_I1(I, Secret,Kir);
|
|
claim_I2(I, Nisynch);
|
|
claim_I3(I, Empty, (Fresh,Kir));
|
|
}
|
|
|
|
role R
|
|
{
|
|
const Nr: Nonce;
|
|
var Ni: Nonce;
|
|
var T: Ticket;
|
|
var Kir: SessionKey;
|
|
|
|
read_1(I,R, I,Ni);
|
|
send_2(R,S, R, Nr, {I,Ni}k(R,S) );
|
|
read_4(I,R, {I,Kir,Nr}k(R,S) , {Nr}Kir );
|
|
|
|
claim_R1(R, Secret,Kir);
|
|
claim_R2(R, Nisynch);
|
|
claim_R3(R, Empty, (Fresh,Kir));
|
|
}
|
|
|
|
role S
|
|
{
|
|
const Kir: SessionKey;
|
|
var Ni,Nr: Nonce;
|
|
|
|
read_2(R,S, R, Nr, {I,Ni}k(R,S) );
|
|
send_3(S,I, Nr, {R,Kir,Ni}k(I,S), {I,Kir,Nr}k(R,S) );
|
|
}
|
|
}
|
|
|
|
const Alice,Bob,Simon : Agent;
|
|
|
|
run yahalom-BAN.I(Agent,Agent,s);
|
|
run yahalom-BAN.I(Agent,Agent,s);
|
|
run yahalom-BAN.R(Agent,Agent,s);
|
|
|